1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
xwayland_libs = []
xwayland_required = [
'xcb',
'xcb-composite',
'xcb-render',
'xcb-xfixes',
]
xwayland_optional = [
'xcb-errors',
'xcb-icccm',
]
foreach lib : xwayland_required
dep = dependency(lib, required: get_option('xwayland'))
if not dep.found()
subdir_done()
endif
xwayland_libs += dep
endforeach
foreach lib : xwayland_optional
dep = dependency(lib, required: get_option(lib))
if dep.found()
xwayland_libs += dep
conf_data.set10('WLR_HAS_' + lib.underscorify().to_upper(), true)
endif
endforeach
lib_wlr_xwayland = static_library(
'wlr_xwayland',
files(
'selection/dnd.c',
'selection/incoming.c',
'selection/outgoing.c',
'selection/selection.c',
'sockets.c',
'xwayland.c',
'xwm.c',
),
include_directories: wlr_inc,
dependencies: [
wayland_server,
xwayland_libs,
xkbcommon,
pixman,
],
)
wlr_parts += lib_wlr_xwayland
conf_data.set10('WLR_HAS_XWAYLAND', true)
|
