From fd3fa760d336312acafeb6812b5b0068f5851f27 Mon Sep 17 00:00:00 2001
From: Scott Anderson <scott@anderso.nz>
Date: Fri, 24 Aug 2018 19:35:02 +1200
Subject: Revert "Revert "Merge pull request #1194 from
 ascent12/meson_feature""

This reverts commit 9c886f20b97b6ab1ac85b849f1fe7f16eb199ff0.
---
 backend/x11/meson.build | 44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)
 create mode 100644 backend/x11/meson.build

(limited to 'backend/x11/meson.build')

diff --git a/backend/x11/meson.build b/backend/x11/meson.build
new file mode 100644
index 00000000..1164df1e
--- /dev/null
+++ b/backend/x11/meson.build
@@ -0,0 +1,44 @@
+x11_libs = []
+x11_required = [
+	'xcb',
+	'x11-xcb',
+]
+x11_optional = [
+	'xcb-xkb',
+]
+
+foreach lib : x11_required
+	dep = dependency(lib, required: get_option('x11-backend'))
+	if not dep.found()
+		subdir_done()
+	endif
+
+	x11_libs += dep
+endforeach
+
+foreach lib : x11_optional
+	dep = dependency(lib, required: get_option(lib))
+	if dep.found()
+		x11_libs += dep
+		conf_data.set('WLR_HAS_' + lib.underscorify().to_upper(), true)
+	endif
+endforeach
+
+lib_wlr_backend_x11 = static_library(
+	'wlr_backend_x11',
+	files(
+		'backend.c',
+		'input_device.c',
+		'output.c',
+	),
+	include_directories: wlr_inc,
+	dependencies: [
+		wayland_server,
+		pixman,
+		xkbcommon,
+		x11_libs,
+	],
+)
+
+backend_parts += lib_wlr_backend_x11
+conf_data.set('WLR_HAS_X11_BACKEND', true)
-- 
cgit v1.2.3