render/gles2: move shaders to individual files

Instead of having a C file with strings for each shader, move each
shader into its own file. Use a small POSIX shell script to convert
the files into C strings (can't wait for C23 #embed...).

The benefits from this are:

- Improved readability and syntax highlighting.
- Line numbers in shader compiler errors are easier to make sense of.
- Consistency with the Vulkan renderer.
- Shaders will become more complicated as we add color management
  features.

1 files changed, 23 insertions, 0 deletions

diff --git a/render/gles2/shaders/meson.build b/render/gles2/shaders/meson.build
new file mode 100644
index 00000000..626c2b14
--- /dev/null
+++ b/render/gles2/shaders/meson.build
@@ -0,0 +1,23 @@
+embed = find_program('./embed.sh', native: true)
+
+shaders = [
+	'quad.vert',
+	'quad.frag',
+	'tex.vert',
+	'tex_rgba.frag',
+	'tex_rgbx.frag',
+	'tex_external.frag',
+]
+
+foreach name : shaders
+	output = name.underscorify() + '_src.h'
+	var = name.underscorify() + '_src'
+	wlr_files += custom_target(
+		output,
+		command: [embed, var],
+		input: name,
+		output: output,
+		feed: true,
+		capture: true,
+	)
+endforeach