Merge branch 'wlroots'

1 files changed, 73 insertions, 0 deletions

diff --git a/protocols/meson.build b/protocols/meson.build
new file mode 100644
index 00000000..7f83b16b
--- /dev/null
+++ b/protocols/meson.build
@@ -0,0 +1,73 @@
+wl_protocol_dir = wayland_protos.get_pkgconfig_variable('pkgdatadir')
+
+wayland_scanner = find_program('wayland-scanner')
+
+wayland_scanner_code = generator(
+	wayland_scanner,
+	output: '@BASENAME@-protocol.c',
+	arguments: ['code', '@INPUT@', '@OUTPUT@'],
+)
+
+wayland_scanner_client = generator(
+	wayland_scanner,
+	output: '@BASENAME@-client-protocol.h',
+	arguments: ['client-header', '@INPUT@', '@OUTPUT@'],
+)
+
+wayland_scanner_server = generator(
+	wayland_scanner,
+	output: '@BASENAME@-protocol.h',
+	arguments: ['server-header', '@INPUT@', '@OUTPUT@'],
+)
+
+client_protocols = [
+	[wl_protocol_dir, 'stable/xdg-shell/xdg-shell.xml'],
+	['wlr-layer-shell-unstable-v1.xml'],
+	['wlr-input-inhibitor-unstable-v1.xml']
+]
+
+server_protocols = [
+	[wl_protocol_dir, 'unstable/xdg-shell/xdg-shell-unstable-v6.xml'],
+	['wlr-layer-shell-unstable-v1.xml'],
+	['wlr-input-inhibitor-unstable-v1.xml']
+]
+
+client_protos_src = []
+client_protos_headers = []
+
+server_protos_src = []
+server_protos_headers = []
+
+foreach p : client_protocols
+	xml = join_paths(p)
+	client_protos_src += wayland_scanner_code.process(xml)
+	client_protos_headers += wayland_scanner_client.process(xml)
+endforeach
+
+foreach p : server_protocols
+	xml = join_paths(p)
+	server_protos_src += wayland_scanner_code.process(xml)
+	server_protos_headers += wayland_scanner_server.process(xml)
+endforeach
+
+lib_client_protos = static_library(
+	'client_protos',
+	client_protos_src + client_protos_headers,
+	dependencies: [wayland_client]
+) # for the include directory
+
+client_protos = declare_dependency(
+	link_with: lib_client_protos,
+	sources: client_protos_headers,
+)
+
+lib_server_protos = static_library(
+	'server_protos',
+	server_protos_src + server_protos_headers,
+	dependencies: [wayland_client]
+) # for the include directory
+
+server_protos = declare_dependency(
+	link_with: lib_server_protos,
+	sources: server_protos_headers,
+)